# xotcl script to turn man pages into xowiki pages
# Gustaf Neumann, Jan 21, 2006
package require XOTcl; namespace import -force ::xotcl::*
package require xotcl::serializer

set rman /usr/local/bin/rman
set path /usr/local/man/mann

namespace eval ::xowiki {
  Class create Page -parameter {
    {lang en} {description ""} {text ""} {nls_language en_US}
    {mime_type text/html} title text
  }

  set c 0
  set code 0
  set tmpfile /tmp/spool.[pid]
  set toc [Page create page[incr c] -title en:#toc]
  $toc set text "<h2>Manual pages</h2>\n<ul>\n"
  foreach full_name [glob /$path/*] {
    regexp {/([^/]+)$} $full_name _ man_page
    if {[regexp {^(.*)[.]([^.]+)$} $man_page _ name section]} {
      set p [Page create page[incr c] -title en:$man_page]
      $toc append text "<li>\[\[en:$man_page\]\]</li>\n"
      catch {exec $rman -f HTML $path/$man_page > $tmpfile}
      set f [open $tmpfile]; set page [read $f]; close $f
      file delete $tmpfile
      set text ""
      set state 0
      foreach l [split $page \n] {
	if {$state == 0} {
	  # skip until body
	  if {![string match "<body*" $l]} continue
	  set state 1
	  continue
	}
	if {[string match "*</body>*" $l]} continue
	if {[string match "*</html>*" $l]} continue
	if {[string match "*<code>*" $l]} {set code 1}
	if {[string match "*</code>*" $l]} {set code 0}
	if {$code} {regsub -all { } $l {\&nbsp;} l }
	regsub -all {<a href='([^']+)'>[^<]+</a>} $l {[[en:\1]]} l
	append text $l\n
      }
      $p text [list $text text/html]
      append source [::Serializer deepSerialize $p]
    }
  }
  $toc append text "</ul>\n"
  $toc set text [list [$toc set text] text/html]
  append source [::Serializer deepSerialize $toc]
  puts $source
}